Search Contextures Sites

 

30 Excel Functions in 30 Days

 

 

Contextures
Excel news
by email

We respect your email privacy

 

 

 

Learn how to create Excel dashboards.

 

 

Your worksheet formulas can create traffic-light charts, highlight chart elements, assign number formats, and more.

 

 

 

 

 

Learn how to create Excel dashboards.

 

 

 

30 Excel Functions in 30 Days

 

 

 

Learn how to create Excel dashboards.

 

 

 

Learn how to create Excel dashboards.

 

 

Live-link your Excel dashboards to nearly any web data.

 

 

 

Learn how to create Excel dashboards.

 

 

 

Learn how to create Excel dashboards.

 

Learn how to create Excel dashboards.

Excel Sum Function Examples

Sum a range of cells -- SUM Function

The SUM function will add the numbers in a range of cells. Its syntax is:
    =SUM(number1, number2,...number30).

The arguments (e.g. number1) for the SUM function can be cell references, or typed into the formula. The following example uses one argument -- a reference to cells A1:A4.

  1. Select the blank cell in the row below the cells that you want to sum, cell A5 in this example.
  2. Click the AutoSum command on the Ribbon's Home tab

Excel AutoSum

Or, use the keyboard shortcut: Alt + =

A SUM formula will appear in the active cell, with a reference to the cells above. If the cells are not automatically included, you can drag over the cells, to select them.

Excel Sum Function

  1. Press the Enter key to complete the entry.

Note: Instead of using the AutoSum button, you can type the SUM formula into the cell.

Grand Total a range of cells

You can calculate row totals, column totals, and a grand total for a range of cell, all in one step.

  1. Select the range of cells, and the blank row below the range, and the blank cells in the column to the right (cells A1:D5 in the example below)

    2. Excel Sum Grand Total

  2. Click the AutoSum button on the Ribbon's Home tab. A SUM formula will be automatically entered for each Total.

See the simple steps in this short Excel Grand Totals video.

Video: Running Total for a Range of Cells

To see a running total in each row of an Excel table, you can use the SUM function, with the starting row locked as an absolute reference. Watch this video to see how to set up the formulas, and lock the starting row. The written instructions are below the video.

Running Total for a Range of Cells

Instead of calculating a total at the bottom of a range of cells, you can use a formula to show the running total in each row.

In the screen shot below, amounts are entered in column C, and a running total is calculated in column D.

Enter this formula in cell D2, and copy down to cell D6:

=SUM(C$2:C2)

sum running total formula

The formula uses an absolute reference to row 2 as the starting point -- C$2 -- and a relative reference to the ending point -- C2

This ensures that the starting point will not change when you copy the formula down to the rows below. Here is the formula in cell D6 -- the starting point has stayed the same and the ending point is in the current row -- C6

=SUM(C$2:C6)

sum running total formula

Sum a range of cells -- OFFSET

If you insert a row directly above the SUM function in the previous example, the new row may not be included in the SUM. It may continue to sum cells A1:A4, and ignore A5. To ensure that new rows are included in the total, you can use the OFFSET function with the SUM function.

  1. Select cell A5.
  2. Enter the following formula:
       =SUM(A1:OFFSET(A5,-1,0))

    3. Excel Sum Function OFFSET

  3. Press the Enter key to complete the entry.
  4. Insert a row above row 5
  5. Type a number in cell A5, and it will be included in the total in cell A6

Sum cells that match criteria -- SUMIF

Match criterion exactly

You can calculate a total for rows that meet a specific criterion. In this example only the rows with Pen orders will be included in the total.

  1. Select the cell in which you want to see the total
  2. Type an equal sign (=) to start the formula
  3. Type:   SUMIF(
  4. Select the cells that contain the values to check for the criterion. In this example, cells A2:A10 will be checked
  5. Type a comma, to separate the arguments
  6. Type the criterion. In this example, you're checking for text, so type the word in double quotes:   "Pen"
    Note: upper and lower case are treated equally
  7. Type a comma, to separate the arguments
  8. Select the cells that contain the values to sum. In this example, cells B2:B10 will be summed
  9. The completed formula is:
      =SUMIF(A2:A10,"Active",B2:B10)
  10. Press the Enter key to complete the entry

    Excel SUMIF

Note: Instead of typing the criterion in a formula, you can refer to a cell. For example, the formula in step 9 above could be changed to:
    =SUMIF(A2:A10, B12, B2:B10)
if cell B12 contained the text — pen.

Match criterion in a string

You can add cells that contain a criterion as part of the cell's contents. In this example all Pen, Gel Pen, and Pencil orders will be summed, because they contain the string "pen".

  1. Select the cell in which you want to see the total (cell A12 in this example)
  2. Type an equal sign (=) to start the formula
  3. Type:   SUMIF(
  4. Select the cells that contain the values to check for the criterion. In this example, cells A2:A10 will be checked
  5. Type a comma, to separate the arguments
  6. Type the criterion. In this example, you're checking for text, so type the word in double quotes, with one or more asterisk (*) wildcard characters:   "*Pen*"
    Note: upper and lower case are treated equally
  7. Type a comma, to separate the arguments
  8. Select the cells that contain the values to sum. In this example, cells B2:B10 will be summed
  9. Type a closing bracket. The completed formula is: =SUMIF(A2:A10,"*Pen*",B2:B10)
  10. Press the Enter key to complete the entry
  11. The result will be 53, the total of rows that contain the string, "Pen"

    Excel SUM Criteria

Note: Instead of typing the criterion in a formula, you can refer to a cell. For example, the formula in step 9 above could be changed to:
    =SUMIF(A2:A10,"*" & B12 & "*",B2:B10)
if cell B12 contained the text — pen. 

Criterion and operator

You can use an operator with a criterion. In this example only the rows where the number of sales reps is greater than or equal to ten will be included in the total.

  1. Select the cell in which you want to see the total
  2. Type an equal sign (=) to start the formula
  3. Type:   SUMIF(
  4. Select the cells that contain the values to check for the criterion. In this example, cells B2:B10 will be checked
  5. Type a comma, to separate the arguments
  6. Type the criterion. In this example, you're checking for rows where the number of visits is greater than or equal to 10. The >= operator is used before the number, and the entire criterion is enclosed in double quotes.
  7. Type a comma, to separate the arguments
  8. Select the cells that contain the values to sum
  9. Type a closing bracket. The completed formula is:
      =SUMIF(B2:B10,">=10",C2:C10)
  10. Press the Enter key to complete the entry
  11. The result will be 183, the total of rows with ten or more sales reps.

    Excel Sum Criterion Operator

Note: Instead of typing the criterion in a formula, you can refer to a cell. For example, the formula in step 9 above could be changed to:
   =SUMIF(B2:B10,">=" & B12,C2:C10)
if cell B12 contained the number — 10. 

Sum cells that match multiple criteria -- SUMIFS

Match multiple criteria

In Excel 2007 and later versions, you can use the SUMIFS function to calculate a total for rows that meet two or more criteria. In this example only the rows where the status is "Active" and the number of visits is greater than or equal to ten will be included in the total.

A step by step video is below the written instructions.

Excel Sum Match Criteria

  1. Select the cell in which you want to see the total
  2. Type an equal sign (=) to start the formula
  3. Type:   SUMIFS(
  4. Select the cells that contain the values to sum. In this example, cells C2:C6 will be summed
  5. Type a comma, then select the cells that contain the values to check for the first criterion. In this example, cells A2:A6 will be checked
  6. Type a comma, and then type the first criterion, "Active"
  7. Type a comma, then select the cells that contain the values to check for the second criterion. In this example, cells B2:B6 will be checked
  8. Type a comma, and then type the second criterion:  " >=10"
  9. Finish with a closing bracket: )
  10. The completed formula is:
    =SUMIFS(C2:C6,A2:A6,"Active",B2:B6,">=10")
  11. Press the Enter key to complete the entry  

Video: SUMIFS Function

Sum cells that match multiple criteria -- SUMPRODUCT

Match multiple criteria

In Excel 2003 and earlier, you can use the SUMPRODUCT function to calculate a total for rows that meet two or more criteria. If you're using Excel 2007 or later, you should use the SUMIFS function, as described in the previous section.

In this example only the rows where the status is "Active" and the number of visits is greater than or equal to ten will be included in the total.

Excel Sum Match Criteria

  1. Select the cell in which you want to see the total
  2. Type an equal sign (=) to start the formula
  3. Type:   SUMPRODUCT(--(
  4. Select the cells that contain the values to check for the first criterion. In this example, cells A2:A6 will be checked
  5. Type the first criterion:   ="Active"
  6. Type ),--(
  7. Select the cells that contain the values to check for the second criterion. In this example, cells B2:B6 will be checked
  8. Type the second criterion:   >=10
  9. Type ),--(
  10. Select the cells that contain the values to sum. In this example, cells C2:C6 will be summed
  11. Finish with closing brackets: ))
  12. The completed formula is:
    =SUMPRODUCT(--(A2:A6="Active"), --(B2:B6>=10),--(C2:C6))
  13. Press the Enter key to complete the entry  

Sum the Top 5 Numbers in a List

Use the SUM function and LARGE functions together, to add the largest numbers in the list.

Version 1 -- Few Top Numbers

If a few numbers are to be summed, e.g. top 3, you can type the numbers into the formula. For example:

=SUM(LARGE(A1:A7,{1,2,3}))  

The result is 70+60+50 = 180

Note: The second 50 is not included in the result, even though it is tied for 3rd place.

Excel Sum Top 5 Cells

Version 2 -- Many Top Numbers

If many top numbers are to be summed you can include the INDIRECT function in the formula with the SUM function. In the INDIRECT function, use row numbers that represent the numbers you want to include. In this example, rows 1:10 are used, so the top 10 numbers in the referenced range will be summed.

  1. Type the formula:
      =SUM(LARGE(A1:A50,ROW(INDIRECT("1:10"))))
  2. This is an array formula, and must be array-entered. To do this, hold the Ctrl and Shift keys, and press Enter

Version 3 -- Variable Top Numbers

If a variable number of top numbers are to be summed you can include the INDIRECT function in the formula with the SUM function, as shown above, and refer to a cell that holds the variable..

  1. In cell C1, type the number of top cells, e.g. 10
  2. Type the formula:
      =SUM(LARGE(A1:A7,ROW(INDIRECT("1:"&C1))))
  3. This is an array formula, and must be array-entered. To do this, hold the Ctrl and Shift keys, and press Enter

Video: Sum Amounts in a Date Range

To sum amounts based on a date range, you can use the SUMIFS function in Excel 2007 or later versions. Watch this video to see the steps, and the written instructions are below the video.

Sum Amounts in a Date Range

To total the amounts in a specific date range, use the SUMIFS function (Excel 2007 and later) or the SUMIF function.

In this example, a Start date and an End date are entered on the worksheet. Dates are in column A, and units sold are in column B.

Excel Sum date range

Use SUMIFS to Calculate Total for a Date Range

For Excel 2007, and later versions, you can use the SUMIFS function to calculate a total based on multiple criteria. We'll use a SUMIFS formula to total all the units where the sales date is:

  • on or after the Start date
    • AND
  • on or before the End date.

Here is the formula that is entered in cell D5:

=SUMIFS($B$2:$B$9,$A$2:$A$9,">=" & $D$2, $A$2:$A$9,"<=" & $E$2)

  • The first argument, $B$2:$B$9, is the range with the numbers that we want to sum.
  • The 2nd argument, $A$2:$A$9, is the range to check for criteria 1.
  • The 3rd argument, ">=" & $D$2, is the range with the value for criteria 1 (the Start date), and the operator to use with that value (greater than or equal to)
  • The 4th argument, $A$2:$A$9, is the range to check for criteria 2.
  • The 5th argument, "<=" & $E$2, is the range with the value for criteria 2 (the End date), and the operator to use with that value (less than or equal to)

Excel Sum date range SUMIFS

In this example, the result for the selected date range is a total of 494 units sold. To verify, you can select cells B3:B6, and look at the total shown in Excel's Status Bar.

Excel Sum date range verify

To get the total units for a different date range, change the Start date in cell D2, and/or the End date in cell E2.

Use SUMIF to Calculate Total for a Date Range

For Excel 2003, and earier versions, you can use the SUMIF function to calculate a total based on a single criterion. We'll use one SUMIF formula to total all the units where the sales date is:

  • on or after the Start date

Then we'll use another SUMIF formula to subtract any values where there date is

  • after the End date.

Here is the formula that is entered in cell D5:

=SUMIF($A$2:$A$9,">=" &$D$2,$B$2:$B$9)
- SUMIF($A$2:$A$9,">" &$E$2,$B$2:$B$9)

  • The range, $A$2:$A$9, contains the numbers that we want to sum.
  • The criteria, ">=" & $D$2, is the range with the Start date, and the operator to use with that value (greater than or equal to)
  • The range, $B$2:$B$9, is the range to check for the date
  • The criteria, ">" & $E$2, is the range with the End date, and the operator to use with that value (greater than)

Excel Sum date range SUMIF

In this example, the result for the selected date range is a total of 494 units sold. To verify, you can select cells B3:B6, and look at the total shown in Excel's Status Bar.

Excel Sum date range verify

To get the total units for a different date range, change the Start date in cell D2, and/or the End date in cell E2.

Sum a Filtered List With SUBTOTAL

After you filter the rows in a list, you can use the SUBTOTAL function, instead of the SUM function, to sum the numbers in the visible rows.

  1. Apply an AutoFilter to the table. There are instructions here -- AutoFilter Basics
  2. Filter at least one of the columns in the table. In this example, the first column has been filtered for Binders.
  3. Select the cell immediately below the column you want to sum.
  4. Click the AutoSum button on the Ribbon's Home tab.
    • If you want the SUBTOTAL function in a cell other than the one directly below the filtered list, you can type the formula, instead of using the AutoSum button.
  5. A SUBTOTAL formula will be automatically inserted, totalling the visible cells in the column
    • The first argument in the SUBTOTAL function is a function number, that specifies how the numbers should be calculated. There is a 9 in this example, which tells Excel to SUM the numbers.
    • Other function numbers can be used, such as 1 for AVERAGE, and 3 for COUNTA. Look in Excel's Help for a complete list.
  6. Press the Enter key to complete the formula entry.

Note: In Excel 2003 and later versions, you can use the formula:
    =SUBTOTAL(109,B2:B9)
to subtotal visible cells in a range where rows have been manually hidden, or filtered.

Excel Sum Subtotal

Video: Sum a Filtered List With AGGREGATE

The AGGREGATE function, introduced in Excel 2010, is similar to the SUBTOTAL function, but it has more functions, and can ignore error values, as well as hidden rows in the data.

Watch this video to see the steps for setting up an AGGREGATE formula, and the written instructions are below the video.

Sum a Filtered List With AGGREGATE

After you filter the rows in a list, you can use the AGGREGATE function, instead of the SUM function, to sum the numbers in the visible rows. This function was introduced in Excel 2010.

Similar to the SUBTOTAL function, AGGREGATE ignores hidden rows, and offers several functions, like SUM or AVERAGE, for the selected data. However, it has 19 functions, compared to SUBTOTAL's 11 functions.

AGGREGATE options

Unlike the SUBTOTAL function, AGGREGATE can be set to ignore errors, as well as hidden rows, and nested SUBTOTAL and AGGREGATE functions.

AGGREGATE options

To sum the values in a filtered list, and ignore hidden rows and errors:

  1. Select the cell where you want the sum
  2. Type =AGGREGATE(
  3. In the list of functions, double-click on 9 - SUM, to add 9 as the first argument.
  4. Type a comma, and in the list of options, double-click on option 3 or option 7. In this example, 3 is the second argument, and the result will ignore hidden rows, errors, and nested AGGREGATE and SUBTOTAL functions.

    5. AGGREGATE options

  5. Type a comma, and select the range of cells that contain the data -- D2:D7 in this example.
  6. Type a bracket, to complete the formula, and press the Enter key.

The completed formula is: =AGGREGATE(9,3,D2:D7)

AGGREGATE options

Download the Sample File

Download the zipped Sum functions sample workbook. The workbook contains the examples for SUM, SUMIF, SUMIFS, SUMPRODUCT, SUBTOTAL and AGGREGATE functions.

Excel Function Tutorials

Sum Functions -- Sum Cells  
VLOOKUP Function  
INDEX / MATCH Functions  
Count Functions -- Count Cells  
INDIRECT Function  

Learn how to create Excel dashboards.

 

Privacy Policy

 

Contextures Inc., Copyright ©2013
All rights reserved.

 

Last updated: May 21, 2013 10:57 AM