Contextures

How to Combine Cells in Excel

How to combine two cells im Excel, with text and numbers, or formulas. Show in one cell, and format numbers and dates. Excel file, step-by-step video, and written instructions

Combine Text and Numbers

Watch this short video to see how to combine cells in Excel, with text and number format. Written steps are below the video.

Combine Text from Multiple Cells

To combine text from multiple cells into one cell, use the & (ampersand) operator.

  1. Select the cell in which you want the combined data
  2. Type an = (equal sign) to start the formula
  3. Click on the first cell
  4. Type the & operator (shift + 7)
  5. Click on the second cell
  6. Press Enter to complete the formula go to top

If the text is in a formatted table, the formula will show structured references, with the column names.

combine text formatted table

If the text is not in a formatted table, the formula will show cell references.

combine text cell references

Add Spaces to Combined Text

When you combine cells with text using the above formula, there is no space between the first and last names. To insert a space, or another character, you can include a text string in the formula.

  1. Select the cell in which you want the combined data
  2. Type an = (equal sign) to start the formula
  3. Click on the first cell
  4. Type the & operator
  5. Type the text string for the character that you want between the words, for example:
    • Space: " " (double quote, space, double quote)
    • Comma Space: ", " (double quote, comma, space, double quote)
    • Semi-colon Space: ", " (double quote, semi-colon, space, double quote)
    • Line break: CHAR(10)
      NOTE: Turn on Wrap Text in the cell, if using a Line Break
  6. Type the & operator
  7. Click on the second cell
  8. Press Enter to complete the formula go to top

If the text is in a formatted table, the formula will show structured references, with the column names.

combine text space formatted table

If the text is not in a formatted table, the formula will show cell references.

combine text space cell references

Add Line Break to Combined Text

Instead of showing characters between the words, you can use the CHAR function, with 10 as its argument, to create a line break. This is the same as typing Alt+Enter in a cell that contains text.

Be sure to format the cell with Wrap Text, to see the line break..

  1. Select the cell in which you want the combined data
  2. Type an = (equal sign) to start the formula
  3. Click on the first cell
  4. Type the & operator
  5. Type CHAR(10)
  6. Type the & operator
  7. Click on the second cell
  8. Press Enter to complete the formula
  9. Format the cell with Wrap Textgo to top

If the text is in a formatted table, the formula will show structured references, with the column names.

combine text line break formatted table

If the text is not in a formatted table, the formula will show cell references.

combine text line break cell references

Combine Cells With Text and a Number

You can combine cells to join a text string with a number from another cell. In this example, text will be added to the payment terms.

  1. Select the cell in which you want the combined data
  2. Type the formula, with text inside double quotes. For example: ="Due in " & A3 & " days"
    NOTE: To separate the text strings from the numbers, end or begin the text string with a space.
  3. Press Enter to complete the formula go to top

combine text line break cell references

Combine Text and Formatted Date

When you combine text with a date, you can format it by using the TEXT function. Without formatting, the date will appear as a number, as in the screen shot below

For example, this simple formula combines a text string ("Today is ") with the current date (using the TODAY function):

  • ="Today is " & TODAY()

When you press Enter, the date appears as a long number, without any date formatting.

  • Today is 41905

combine text date

Add Date Formatting

To combine a text string with a formatted date, use the Excel TEXT function to format the date.

Follow these steps to create the formula:

  1. Select the cell where you want the combined data
  2. Type the formula, with text inside double quotes, and the date inside the TEXT function. For example, to show the full weekday name, for the current date:
    ="Today is " & TEXT(TODAY(),"dddd")
  3. Press Enter to complete the formula

How the TEXT Function works

In the Excel TEXT function: TEXT(TODAY(),"dddd")

  1. Date is the first argument,
  2. Formatting is the second argument.

In this example:

  • The TODAY function returns the current date.
  • The "dddd" formats the date as the full weekday name -- Tuesday

A few more date formats are in the screen shot shown below:

  • "mm-dd-yyyy"
  • "yyyymmdd"
  • "ddd mmm dd yyyy"

combine text date format

NOTE: For other languages, use the applicable date codes, such as "jjjj" for the weekday name in French. To see how to switch between languages, download the sample file from the Functions section on the Excel Sample Files page. Look for FN0046 - Change Language for TEXT Function.

Combine Text and Formatted Numbers

Here are a few examples of using the TEXT function to format numbers.

NOTE: There are more examples of Custom formats on the Microsoft website go to top

combine text number format

  • Format a date as month/day/year:
    •   ="Payment is due " & TEXT(A2,"mm/dd/yyyy")
  • Format a number as currency:
    •   ="Amount due: " & TEXT(A3,"$#,##0.00")& " USD"
  • Format a number as a percentage:
    •    ="Your score is " & TEXT(A4,"0.00%")
  • Format a number as a fraction:
    •    ="Hours worked: " &TEXT(A5,"# ?/?")

Custom Number Format with Text

Instead of using a formula in a cell, another way to combine text with dates or numbers is to use a custom number format. With this method, the dates or numbers are not affected -- they can still be used in other calculations, as numeric values. Only the cell appearance is changed, not the cell value.

Follow these steps to apply a custom number format that combines text and a formatted date.

  1. In cell B4, type this formula, to show the current date: =TODAY()
  2. Right-click cell B4, and click Format Cells
  3. On the Number tab, click on the Date category
  4. Select the date formatting, that you'd like, such as 14-Mar-12
  5. Next, click the Custom category
  6. In the Type box, your selected date format will appear, such as:
    • [$-en-US]d-mmm-yy;@
  7. To add text before and/or after the date, type the text inside double quote mark. For example:
    • "Today is "[$-en-US]d-mmm-yy". Enjoy!";@
  8. Click OK, to apply the formatting

scroll through filter items

The TODAY function in cell B4 still shows the current date, but now it has text before and after it.

And, if you look in the formula bar when the cell is selected, only the TODAY formula shows - none of the text is visible.

date with custom number format that shows text

TEXTJOIN Function

In Excel for Office 365, or Excel 2019 and later versions, you can use the TEXTJOIN function to combine text from multiple ranges, quickly and easily.

NOTE: If you don't have TEXTJOIN, use the ConCat user defined function, to combine text quickly.

This short video shows a couple of TEXTJOIN examples -- how to combine weekday names, and how to combine formatted dates. There are written steps, and more examples, below the video.

Click here to download the sample file that was used in this video.

TEXTJOIN Arguments

The TEXTJOIN function has 3 required arguments:

  • delimiter - A text string to separate the joined text items. Put the delimiter in double quotes, or refer to a cell that contains the delimiter
  • ignore_empty - TRUE, to ignore blank cells, or FALSE, to include them
  • text1 - The text items to join. This can be a text string, or range of cells, or an array of text strings

You can add more text strings, if needed

  • text2, text3, etc.

Example 1 - Simple Join

This example uses a simple TEXTJOIN formula to join all the text in a range of cells - A2:A8. The separator is a comma and space, and blank cells will be ignored.

This formula is in cell D3, and it returns all the days in the list.

=TEXTJOIN(", ",TRUE,A2:A8)

simple TEXTJOIN formula

NOTE

If the formula had FALSE as the setting for ignore_empty, the blank cell (A5) would be included in the result:

Sun, Mon, Tue, , Thu, Fri, Sat

Example 2 - Join with Condition

This example uses an array-entered TEXTJOIN formula to join the text in a range of cells - A2:A8.

  • The separator is a comma and space, and blank cells will be ignored.
  • The IF function checks for an "x" in column B. If an "x" is not found, IF returns an empty string for that weekday, which is ignored by TEXTJOIN, when TRUE is the 2nd argument.

The following formula is in cell D3, and it returns all the days in the list, where there is an "x" in column B.

NOTE: This formula is array-entered, with Ctrl+Shift+Enter

=TEXTJOIN(", ",TRUE,IF(B2:B8="x",A2:A8,""))

array-entered TEXTJOIN formula with IF

Example 3 - Condition and Formatting

This example example is similar to Example 2, but there are dates in column A, instead of weekday names.

  • In the formula, the TEXT function formats the dates as "ddd", to show short weekday names in the result.
  • The delimiter is a line break, created by the CHAR function, with 10 as the code..

=TEXTJOIN(CHAR(10),TRUE, IF(B2:B8="x", TEXT(A2:A8,"ddd"),""))

array-entered TEXTJOIN formula with IF and TEXT

Example 4 - Dynamic array functions

In this example, TEXTJOIN is combined with a few of Excel's new dynamic array functions -- FILTER, SORT and UNIQUE. Dynamic arrays are available in Microsoft 365 plans, Excel for the web, and Excel mobile apps.

The Sales sheet has 2 years of sales data, formatted as an Excel table. The columns are named ranges - YrCol, RegCol, CatCol, NameCol and QtyCol.

annual sales data

On the Targets sheet, there is another table, with a sales target number for each year and category.

In column E, a TEXTJOIN formula creates a list of sales reps who met the sales target, for that row's year and category.

sales targets table

Sales Reps Who Met Target

The TEXTJOIN function combines the results from a few of Excel's new dynamic array functions -- FILTER, SORT and UNIQUE. To show how those functions work, there's a demo on the Report sheet.

There are drop down lists at the top of the sheet, where you can select a year and category. A SUMIFS formula returns the sales target amount for the selected year and category.

Cell B4 is named YrSel, cell C4 is named CatSel, and cell D4 is named TgtSel.

sales targets table

This dynamic array formula is in cell C7, and the results spill down to the cells below, if necessary.

=IFERROR(UNIQUE(SORT(FILTER(NameCol, (YrCol=YrSel) *(CatCol=CatSel) *(QtyCol>=TgtSel)))), "--")

In this formula, the FILTER function returns the rep names from the Name column in the Sales table, if all 3 criteria are met:

  1. The year is equal to the selected year (YrSel)
  2. The category is equal to the selected category (CatSel)
  3. The quantity is greater than or equal to the target amount (TgtSel)

Then, the SORT function puts those names in alphabetical order, and the UNIQUE function removes any duplicate names.

Finally, the IFERROR returns two dashes ("--"), if there is an error in returning the sales rep names. For example, no sales reps reached the target amount for the selected year and category.

Show All Names in One Cell

On the Targets sheet, a similar formulas is used to create a list of sales reps. This is the function in cell E4 on the Targets sheet:

=IFERROR(TEXTJOIN(", ", TRUE, UNIQUE(SORT(FILTER(NameCol, (YrCol=B4) *(CatCol=C4) *(QtyCol>=D4))))), "--")

The TEXTJOIN function combines all the names, separated by a comma and space character, so the results are shown in a single cell, instead of spilling down a column.

sales targets table

Download the Sample Files

Combine Basic: The workbook has the Combine text examples with the & operator, and number formatting. The zipped file is in xlsx format, and does not contain macros.

TEXTJOIN Get Started: Click here to download the sample file for the Get Started with TEXTJOIN video. For Excel 2019 or 365. The zipped file is in xlsx format, and does not contain macros.

TEXTJOIN Examples: This workbook has TEXTJOIN examples 1, 2 and 3, which work in Excel for Microsoft 365, and in Excel 2019 or later versions. The zipped file is in xlsx format, and does not contain macros.

TEXTJOIN Dynamic: This workbook has the TEXTJOIN with Dynamic Arrays examples, which work in Excel for Microsoft 365. The zipped file is in xlsx format, and does not contain macros.

____________

More Function Tutorials

Sum Functions -- Sum Cells

ConCat User Defined Function

REPT Function

SEARCH Function

VLOOKUP Function

INDEX / MATCH Functions

ADDRESS Function

INDIRECT Function

Last updated: October 7, 2020 3:32 PM